0  BEGIN PGM 8235_FR MM 
1  ;Programme CN permettant de mesurer avec précision
2  ;la coordonnée Z de différentes positions d'usinage
3  ;définies dans un tableau de points et de les
4  ;enregistrer dans ce même tableau.
5  ;Dans cet exemple de programme, la CN exécute la
6  ;même routine de mesure sur les cinq faces d'un dé.
7  ;Le tableau de point concerné est défini comme motif
8  ;et la CN exécute un cycle d'usinage défini aux
9  ;positions données.
10 ;La coordonnée Z entrée dans le tableau définit le
11 ;point de départ du cycle de manière à ce que la
12 ;profondeur définie se réfère toujours à la
13 ;coordonnée Z préalablement mesurée.
14 ;
15 BLK FORM 0.1 Z X-25 Y-25 Z-50
16 BLK FORM 0.2  X+25  Y+25  Z+0
17 ;
18 ;MESURE
19 ;
20 ;Appel du palpeur
21 TOOL CALL "TOUCH_PROBE" Z
22 ;
23 ;Face 1
24 PLANE RESET STAY ;Réinitialisation de l'inclinaison
25 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Décalage du point zéro
26 ;Appel du sous-programme permettant d'approcher une position de sécurité
27 CALL LBL "SAFE"
28 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Inclinaison du plan d'usinage
29 ;
30 ;Ouverture du tableau de points pour la face 1 
31 FN 26: TABOPEN 82351.PNT
32 Q52 = 1 ;NOMBRE DE POSITIONS
33 ;Appel du sous-programme de mesure
34 CALL LBL "MEASURE"
35 ;
36 ;Face 2
37 PLANE RESET STAY ;Réinitialisation de l'inclinaison
38 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Décalage du point zéro
39 ;Appel du sous-programme permettant d'approcher une position de sécurité
40 CALL LBL "SAFE"
41 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Inclinaison du plan d'usinage
42 ;
43 ;Ouverture du tableau de points pour la face 2
44 FN 26: TABOPEN 82352.PNT
45 Q52 = 2 ;NOMBRE DE POSITIONS
46 ;Appel du sous-programme de mesure
47 CALL LBL "MEASURE"
48 ;
49 ;Face 3
50 PLANE RESET STAY ;Réinitialisation de l'inclinaison
51 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Décalage du point zéro
52 ;Appel du sous-programme permettant d'approcher une position de sécurité
53 CALL LBL "SAFE"
54 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Inclinaison du plan d'usinage
55 ;
56 ;Ouverture du tableau de points pour la face 3
57 FN 26: TABOPEN 82353.PNT
58 Q52 = 3 ;NOMBRE DE POSITIONS
59 ;Appel du sous-programme de mesure
60 CALL LBL "MEASURE"
61 ;
62 ;Face 4
63 PLANE RESET STAY ;Réinitialisation de l'inclinaison
64 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Décalage du point zéro
65 ;Appel du sous-programme permettant d'approcher une position de sécurité
66 CALL LBL "SAFE"
67 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Inclinaison du plan d'usinage
68 ;
69 ;Ouverture du tableau de points pour la face 4
70 FN 26: TABOPEN 82354.PNT
71 Q52 = 4 ;NOMBRE DE POSITIONS
72 ;Appel du sous-programme de mesure
73 CALL LBL "MEASURE"
74 ;
75 ;Face 5
76 PLANE RESET STAY ;Réinitialisation de l'inclinaison
77 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Décalage du point zéro
78 ;Appel du sous-programme permettant d'approcher une position de sécurité
79 CALL LBL "SAFE"
80 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Inclinaison du plan d'usinage
81 ;
82 ;Ouverture du tableau de points pour la face 5
83 FN 26: TABOPEN 82355.PNT
84 Q52 = 5 ;NOMBRE DE POSITIONS
85 ;Appel du sous-programme de mesure
86 CALL LBL "MEASURE"
87 ;
88 ;USINAGE
89 ;
90 ;Appel d'outil : foret
91 TOOL CALL "DRILL_D8.5" Z S9000 F2500
92 M3
93 CYCL DEF 200 PERCAGE ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q201=-2    ;PROFONDEUR ~
    Q206= AUTO ;AVANCE PLONGEE PROF. ~
    Q202=+5    ;PROFONDEUR DE PASSE ~
    Q210=+0    ;TEMPO. EN HAUT ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q211=+0    ;TEMPO. AU FOND ~
    Q395=+1    ;REFERENCE PROFONDEUR
94 ;
95 ;Face 1
96 PLANE RESET STAY ;Réinitialisation de l'inclinaison
97 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Décalage du point zéro
98 ;Appel du sous-programme permettant d'approcher une position de sécurité
99 CALL LBL "SAFE"
100 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Inclinaison du plan d'usinage
101 ;
102 ;Définition du tableau de points pour la face 1 comme motif de points
103 SEL PATTERN "82351.PNT"
104 ;Appel du sous-programme pour l'usinage
105 CALL LBL "MACHINING"
106 ;
107 ;Face 2
108 PLANE RESET STAY ;Réinitialisation de l'inclinaison
109 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Décalage du point zéro
110 ;Appel du sous-programme permettant d'approcher une position de sécurité
111 CALL LBL "SAFE"
112 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Inclinaison du plan d'usinage
113 ;
114 ;Définition du tableau de points pour la face 2 comme motif de points
115 SEL PATTERN "82352.PNT"
116 ;Appel du sous-programme pour l'usinage
117 CALL LBL "MACHINING"
118 ;
119 ;Face 3
120 PLANE RESET STAY ;Réinitialisation de l'inclinaison
121 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Décalage du point zéro
122 ;Appel du sous-programme permettant d'approcher une position de sécurité
123 CALL LBL "SAFE"
124 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Inclinaison du plan d'usinage
125 ;
126 ;Définition du tableau de points pour la face 3 comme motif de points
127 SEL PATTERN "82353.PNT"
128 ;Appel du sous-programme pour l'usinage
129 CALL LBL "MACHINING"
130 ;
131 ;Face 4
132 PLANE RESET STAY ;Réinitialisation de l'inclinaison
133 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Décalage du point zéro
134 ;Appel du sous-programme permettant d'approcher une position de sécurité
135 CALL LBL "SAFE"
136 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Inclinaison du plan d'usinage
137 ;
138 ;Définition du tableau de points pour la face 4 comme motif de points
139 SEL PATTERN "82354.PNT"
140 ;Appel du sous-programme pour l'usinage
141 CALL LBL "MACHINING"
142 ;
143 ;Face 5
144 PLANE RESET STAY ;Réinitialisation de l'inclinaison
145 ;Nullpunktverschiebung
146 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Décalage du point zéro
147 ;Appel du sous-programme permettant d'approcher une position de sécurité
148 CALL LBL "SAFE"
149 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Inclinaison du plan d'usinage
150 ;
151 ;Définition du tableau de points pour la face 5 comme motif de points
152 SEL PATTERN "82355.PNT"
153 ;Appel du sous-programme pour l'usinage
154 CALL LBL "MACHINING"
155 ;
156 ;Appel du sous-programme permettant d'approcher une position de sécurité
157 CALL LBL "SAFE"
158 PLANE RESET TURN FMAX ;Réinitialisation de l'inclinaison
159 ;
160 ;Fin du programme
161 M30
162 ;
163 ;Sous-programmes
164 ;Approche d'une position de sécurité qui dépend de la machine
165 LBL "SAFE"
166 M140 MB MAX F9999
167 L  Z+0 R0 FMAX M91
168 L  X+0  Y+0 R0 FMAX M91
169 LBL 0
170 ;
171 ;Mesure
172 LBL "MEASURE"
173 Q50 = 0 ;Première ligne
174 Q51 = Q52 - 1 ;Calcul du nombre de répétitions
175 LBL "LOOP"
176 ;Lecture des coordonnées XY pour la mesure
177 FN 28: TABREAD Q55 =Q50 /"X,Y"
178 TCH PROBE 427 MESURE COORDONNEE ~
    Q263=+Q55  ;1ER POINT 1ER AXE ~
    Q264=+Q56  ;1ER POINT 2EME AXE ~
    Q261=+0    ;HAUTEUR DE MESURE ~
    Q320=+5    ;DISTANCE D'APPROCHE ~
    Q272=+3    ;AXE DE MESURE ~
    Q267=-1    ;SENS DEPLACEMENT ~
    Q260=+15   ;HAUTEUR DE SECURITE ~
    Q281=+0    ;PROCES-VERBAL MESURE ~
    Q288=+0    ;COTE MAX. ~
    Q289=+0    ;COTE MIN. ~
    Q309=+0    ;ARRET PGM SI ERREUR ~
    Q330=+0    ;OUTIL ~
    Q498=+0    ;INVERSER OUTIL ~
    Q531=+0    ;ANGLE DE REGLAGE
179 ;Enregistrement du résultat de la mesure en Z, dans le fichier de points
180 FN 27: TABWRITE Q50 /"Z" = Q160
181 Q50 = Q50 + 1 ;Incrémentation du numéro de ligne
182 CALL LBL "LOOP" REPQ51
183 LBL 0
184 ;
185 ;Usinage
186 LBL "MACHINING"
187 L  X+0  Y+0  Z+50 R0 FMAX ;Prépositionnement
188 CYCL CALL PAT FMAX ;Appel du cycles aux positions du tableau de points
189 LBL 0
190 END PGM 8235_FR MM