0 BEGIN PGM 13_002_1_FR MM
1 ;Programme permettant d'usiner l'arri�re du
2 ;bo�tier de la montre.
3 ;La pi�ce est serr�e sur 4 mm par le bas afin
4 ;de pouvoir r�aliser int�gralement l'usinage
5 ;ext�rieur.
6 ;Pour pouvoir aligner la pi�ce, en vue d'usiner
7 ;la deuxi�me face et de d�finir le point d'origine,
8 ;les trous sont perc�s � travers la pi�ce.
9 ;
10 BLK FORM 0.1 Z X-50 Y-7.5 Z-43
11 BLK FORM 0.2 X+50 Y+92.5 Z+2
12 ;
13 ;Appel de l'outil pour la surface transversale
14 TOOL CALL 11 Z S9550 F2000
15 L Z+100 R0 FMAX M3
16 ;
17 ;Usinage de la surface transversale
18 CYCL DEF 233 FRAISAGE TRANSVERSAL ~
Q215=+0 ;OPERATIONS D'USINAGE ~
Q389=+4 ;STRATEGIE FRAISAGE ~
Q350=+1 ;SENS DE FRAISAGE ~
Q218=+100 ;1ER COTE ~
Q219=+100 ;2EME COTE ~
Q227=+2 ;PT INITIAL 3EME AXE ~
Q386=+0 ;POINT FINAL 3EME AXE ~
Q369=+0.2 ;SUREP. DE PROFONDEUR ~
Q202=+5 ;PROF. PLONGEE MAX. ~
Q370=+1 ;FACTEUR RECOUVREMENT ~
Q207= AUTO ;AVANCE FRAISAGE ~
Q385= AUTO ;AVANCE DE FINITION ~
Q253= MAX ;AVANCE PRE-POSIT. ~
Q357=+2 ;DIST. APPR. LATERALE ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q204=+50 ;SAUT DE BRIDE ~
Q347=+0 ;1ERE LIMITE ~
Q348=+0 ;2EME LIMITE ~
Q349=+0 ;3EME LIMITE ~
Q220=+0 ;RAYON D'ANGLE ~
Q368=+0 ;SUREPAIS. LATERALE ~
Q338=+0 ;PASSE DE FINITION
19 L X-50 Y-7.5 R0 FMAX M99
20 ;
21 ;Usinage ext�rieur
22 CYCL DEF 256 TENON RECTANGULAIRE ~
Q218=+98 ;1ER COTE ~
Q424=+100 ;COTE PIECE BR. 1 ~
Q219=+85 ;2EME COTE ~
Q425=+100 ;COTE PIECE BR. 2 ~
Q220=+0.1 ;RAYON / CHANFREIN ~
Q368=+0.2 ;SUREPAIS. LATERALE ~
Q224=+0 ;POSITION ANGULAIRE ~
Q367=+1 ;POSITION DU TENON ~
Q207= AUTO ;AVANCE FRAISAGE ~
Q351=+1 ;MODE FRAISAGE ~
Q201=-38.5 ;PROFONDEUR ~
Q202=+10 ;PROFONDEUR DE PASSE ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q203=+0 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE ~
Q370=+1 ;FACTEUR RECOUVREMENT ~
Q437=+0 ;POSITION D'APPROCHE
23 L X-49 Y+0 R0 FMAX M99
24 L Z+100 R0 FMAX M5 ;D�gagement
25 ;
26 ;Appel de l'outil pour l'usinage de
27 ;la poche
28 TOOL CALL 5 Z S14000 F2500
29 L Z+100 R0 FMAX M3
30 L X+0 Y+50 R0 FMAX
31 CYCL DEF 251 POCHE RECTANGULAIRE ~
Q215=+0 ;OPERATIONS D'USINAGE ~
Q218=+60 ;1ER COTE ~
Q219=+60 ;2EME COTE ~
Q220=+5 ;RAYON D'ANGLE ~
Q368=+0.2 ;SUREPAIS. LATERALE ~
Q224=+0 ;POSITION ANGULAIRE ~
Q367=+0 ;POSITION POCHE ~
Q207= AUTO ;AVANCE FRAISAGE ~
Q351=+1 ;MODE FRAISAGE ~
Q201=-16 ;PROFONDEUR ~
Q202=+5 ;PROFONDEUR DE PASSE ~
Q369=+0.2 ;SUREP. DE PROFONDEUR ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q338=+5 ;PASSE DE FINITION ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q203=+0 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE ~
Q370=+1 ;FACTEUR RECOUVREMENT ~
Q366=+2 ;PLONGEE ~
Q385= AUTO ;AVANCE DE FINITION
32 M99
33 L Z+100 R0 FMAX M5 ;D�gagement
34 ;
35 ;Appel de l'outil pour le pointage des trous
36 TOOL CALL 203 Z S6000 F600
37 L Z+100 R0 FMAX M3
38 L X+0 Y+50 R0 FMAX
39 CYCL DEF 240 CENTRAGE ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q343=+1 ;CHOIX DIAM./PROFOND. ~
Q201=-2 ;PROFONDEUR ~
Q344=-9 ;DIAMETRE ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q211=+0 ;TEMPO. AU FOND ~
Q203=-16 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE
40 M99
41 CYCL DEF 240 CENTRAGE ~
Q200=+3 ;DISTANCE D'APPROCHE ~
Q343=+1 ;CHOIX DIAM./PROFOND. ~
Q201=-2 ;PROFONDEUR ~
Q344=-6 ;DIAMETRE ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q211=+0 ;TEMPO. AU FOND ~
Q203=-16 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE
42 PATTERN DEF ~
CIRC1( X+0 Y+50 D46 START+0 NUM4 Z+0 )
43 CYCL CALL PAT FMAX
44 L Z+100 R0 FMAX M5 ;D�gagement
45 ;
46 ;Appel d'outil : foret D5
47 TOOL CALL 227 Z S6000 F400
48 L Z+100 R0 FMAX M3
49 L X+0 Y+50 R0 FMAX
50 CYCL DEF 200 PERCAGE ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q201=-28 ;PROFONDEUR ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q202=+5 ;PROFONDEUR DE PASSE ~
Q210=+0 ;TEMPO. EN HAUT ~
Q203=-16 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE ~
Q211=+0 ;TEMPO. AU FOND ~
Q395=+1 ;REFERENCE PROFONDEUR
51 CYCL CALL PAT FMAX
52 L Z+100 R0 FMAX M5 ;D�gagement
53 ;
54 ;Appel d'outil : foret D8
55 TOOL CALL 230 Z S5000 F400
56 L Z+100 R0 FMAX M3
57 L X+0 Y+50 R0 FMAX
58 CYCL DEF 200 PERCAGE ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q201=-28 ;PROFONDEUR ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q202=+8 ;PROFONDEUR DE PASSE ~
Q210=+0 ;TEMPO. EN HAUT ~
Q203=-16 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE ~
Q211=+0 ;TEMPO. AU FOND ~
Q395=+1 ;REFERENCE PROFONDEUR
59 M99
60 L Z+100 R0 FMAX M5 ;D�gagement
61 ;
62 ;Appel de l'outil pour l'�bavurage du
63 ;contour ext�rieur et de la poche
64 TOOL CALL 170 Z S11000 F900 DR-2.5
65 L Z+100 R0 FMAX M3
66 CYCL DEF 256 TENON RECTANGULAIRE ~
Q218=+98 ;1ER COTE ~
Q424=+98.1 ;COTE PIECE BR. 1 ~
Q219=+85 ;2EME COTE ~
Q425=+85.1 ;COTE PIECE BR. 2 ~
Q220=+0.1 ;RAYON / CHANFREIN ~
Q368=+0 ;SUREPAIS. LATERALE ~
Q224=+0 ;POSITION ANGULAIRE ~
Q367=+1 ;POSITION DU TENON ~
Q207= AUTO ;AVANCE FRAISAGE ~
Q351=+1 ;MODE FRAISAGE ~
Q201=-0.7 ;PROFONDEUR ~
Q202=+1 ;PROFONDEUR DE PASSE ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q203=+0 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE ~
Q370=+1 ;FACTEUR RECOUVREMENT ~
Q437=+0 ;POSITION D'APPROCHE
67 L X-49 Y+0 R0 FMAX M99
68 L X+0 Y+50 R0 FMAX
69 CYCL DEF 251 POCHE RECTANGULAIRE ~
Q215=+2 ;OPERATIONS D'USINAGE ~
Q218=+60 ;1ER COTE ~
Q219=+60 ;2EME COTE ~
Q220=+5 ;RAYON D'ANGLE ~
Q368=+0.1 ;SUREPAIS. LATERALE ~
Q224=+0 ;POSITION ANGULAIRE ~
Q367=+0 ;POSITION POCHE ~
Q207= AUTO ;AVANCE FRAISAGE ~
Q351=+1 ;MODE FRAISAGE ~
Q201=-1 ;PROFONDEUR ~
Q202=+1 ;PROFONDEUR DE PASSE ~
Q369=+0 ;SUREP. DE PROFONDEUR ~
Q206= AUTO ;AVANCE PLONGEE PROF. ~
Q338=+5 ;PASSE DE FINITION ~
Q200=+2 ;DISTANCE D'APPROCHE ~
Q203=+0 ;COORD. SURFACE PIECE ~
Q204=+50 ;SAUT DE BRIDE ~
Q370=+1 ;FACTEUR RECOUVREMENT ~
Q366=+2 ;PLONGEE ~
Q385= AUTO ;AVANCE DE FINITION
70 M99
71 L Z+100 R0 FMAX M30 ;D�gagement
72 END PGM 13_002_1_FR MM